home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh4x
/
sh45a.d64
/
listing 5
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
29 lines
10 REM * BEISPIEL 2 *
20 REM ERZEUGEN MEHRFARBIGER SELBSTDEFINIERTER ZEICHEN
31 POKE 56334,PEEK(56334) AND 254:POKE 1,PEEK(1) AND 251
35 FOR I=0 TO 63 :REM ZU KOPIERENDE ZEICHEN
36 FOR J=0 TO 7 :REM ALLE 8 BYTES PRO ZEICHEN
37 POKE 12288+I*8+J,PEEK(53248+I*8+J):REM KOPIERE EIN BYTE
38 NEXT J,I :REM NAECHSTES BYTE ODER ZEICHEN
39 POKE 1,PEEK(1) OR 4:POKE 56334,PEEK(56334) OR 1
40 POKE 53272,(PEEK(53272) AND 240) + 12:REM ZEICHENRAM EINSCHALTEN
50 POKE 53270,PEEK(53270) OR 16
51 POKE 53281,0 :REM HINTERGRUNDFARBE 0 AUF SCHWARZ
52 POKE 53282,2 :REM HINTERGRUNDFARBE 1 AUF ROT
53 POKE 53283,7 :REM HINTERGRUNDFARBE 2 AUF GELB
60 FOR ZEIC=60 TO 63 :REM NEUE ZEICHEN 60 BIS 63
80 FOR BYTE=0 TO 7 :REM ALLE 8 BYTES PRO ZEICHEN
100 READ ZAHL :REM LESE 1/8 ZEICHENDATEN
120 POKE 12288+(8*ZEIC)+BYTE,ZAHL:REM SPEICHERN IM ZEICHENRAM
140 NEXT BYTE,ZEIC
150 PRINT"[147]"TAB(255)CHR$(60)CHR$(61)TAB(55)CHR$(62)CHR$(63)
160 REM ZEILE 150 BRINGT DIE NEUEN ZEICHEN AUF DEN BILDSCHIRM
170 GET A$ :REM ERWARTET TASTENDRUCK
180 IF A$="" THEN 170 :REM SONST NEUER VERSUCH
190 POKE 53272,21:POKE 53270,PEEK(53270) AND 239:REM NORMALER ZEICHENSATZ
200 DATA 129,37,21,29,93,85,85,85 :REM ZEICHENDATEN FUER ZEICHEN 60
210 DATA 66,72,84,116,117,85,85,85:REM ZEICHEN 61
220 DATA 87,87,85,21,8,8,40,0 :REM ZEICHEN 62
230 DATA 213,213,85,84,32,32,40,0 :REM ZEICHEN 63
240 END